;**********************************************************************
;                                                                     *
;    Filename:	    lamp.asm                                          *
;    Date:                                                            *
;    File Version:                                                    *
;                                                                     *
;    Author:        el@jap.hu                                         *
;    Company:       http://jap.hu/electronic/                         *
;                                                                     * 
;                                                                     *
;**********************************************************************
;
; 001-20031024 first version
; 002-2003101026 implement watchdog
; 003-2003121130
;
; two lamp timers with led indicators
;

        list      p=12F629
        #include <p12F629.inc>

        __CONFIG   _CP_OFF & _WDT_ON & _MCLRE_OFF & _INTRC_OSC_NOCLKOUT & _BODEN_ON

MHZ	EQU	4
dly_a	EQU	.3 * .60 * .100	; delay in 10 ms (seconds *100)
dly_b	EQU	.10 * .60 * .100; delay in 10 ms (seconds *100)


; port bits
BT_A	EQU	2
BT_B	EQU	3
LD_A	EQU	0
LD_B	EQU	1
CT_A	EQU	4
CT_B	EQU	5

; control state bits
DE_A	EQU	0
ON_A	EQU	1
DE_B	EQU	2
ON_B	EQU	3

;***** VARIABLE DEFINITIONS
	CBLOCK 0x20
	dly0	; delay counter 0
	dly1	; delay counter 1
	ct_states ; control state register
	port_state ; next port state

	bt_a	; button states
	prev_bt_a ; prevous button states
	bt_a_cnt ; counter for hold time
	bt_a_holdtime ; min hold time - from EEPROM
	ct_a_time : 2 ; timer delay time - from EEPROM
	ct_a_cnt : 2 ; timer delay counter

	bt_b
	prev_bt_b
	bt_b_cnt ; counter for hold time
	bt_b_holdtime ; from EEPROM
	ct_b_time : 2 ; timer delay time - from EEPROM
	ct_b_cnt : 2 ; timer delay counter

	ENDC

	org 0x2120
	de low dly_a, high dly_a ; delay time
	de 0x03 ; button hold time

	org 0x2130
	de low dly_b, high dly_b ; delay time
	de 0x03 ; button hold time

	org 0
	goto main
	nop
	nop

	retfie

eeread	bsf	STATUS, RP0
	movwf	EEADR
	bsf	EECON1, RD
	movf	EEDATA, W
	bcf	STATUS, RP0
	return

delay10	; delay 10 ms
	movlw	.192
	movwf	dly0
delay_a	movlw	.4 * MHZ
	movwf	dly1
delay_b	decfsz	dly1, F
	goto	delay_b
	decfsz	dly0, F
	goto	delay_a
	return


main	bsf	STATUS, RP0
	bcf	STATUS, RP1
	call	0x3ff
	movwf	OSCCAL
	clrwdt
	clrf	TMR0
	movlw	0x0f	; watchdog prescaler 1:128
	movwf	OPTION_REG
	clrwdt
	movlw	(1<<BT_A) | (1<<BT_B)
	movwf	TRISIO
	movwf	WPU

	bcf	STATUS, RP0
	movlw	7
	movwf	CMCON
	clrf	GPIO

	movlw	0x20	; read timing data from EEPROM
	call	eeread
	movwf	ct_a_time
	movlw	0x21
	call	eeread
	movwf	ct_a_time+1
	movlw	0x22
	call	eeread
	movwf	bt_a_holdtime

	movlw	0x30	; read timing data from EEPROM
	call	eeread
	movwf	ct_b_time
	movlw	0x31
	call	eeread
	movwf	ct_b_time+1
	movlw	0x32
	call	eeread
	movwf	bt_b_holdtime

	clrf	bt_a
	clrf	bt_b
	clrf	ct_states

loop	clrwdt
	call	delay10
	call	state_machine
	goto	loop

state_machine
	clrf	port_state ; ct_X_sub sets port_state bits to H

	call	bt_a_sub
	call	de_a_sub
	call	ct_a_sub

	call	bt_b_sub
	call	de_b_sub
	call	ct_b_sub

	movf	port_state, W
	movwf	GPIO
	return

bt_a_sub
	movf	bt_a, W
	movwf	prev_bt_a

	movlw	(1<<BT_A)
	andwf	GPIO, W
	movwf	bt_a

	xorwf	prev_bt_a, W
	bz	bt_a_unchanged

bt_a_changed
	; button status changed
	btfss	bt_a, BT_A
	goto	bt_a_released

bt_a_pressed
	; button pressed
	clrf	bt_a_cnt

bt_a_unchanged
	btfsc	bt_a, BT_A
	incf	bt_a_cnt, F ; measure pressing time
	return

bt_a_released
	; the button is just released
	movf	bt_a_holdtime, W
	subwf	bt_a_cnt, W
	bnc	bt_a_short

	; the button hold time was long enough
	btfsc	ct_states, ON_A
	goto	bt_a_tst1

	; control output was OFF
	; now turn ON and setup delay
	bsf	ct_states, ON_A
	bsf	ct_states, DE_A

	; setup delay
	movf	ct_a_time, W
	movwf	ct_a_cnt
	movf	ct_a_time+1, W
	movwf	ct_a_cnt+1
	return

bt_a_tst1
	btfss	ct_states, DE_A ; comment this line out to not turn ON forever

	; control output was ON forever
	; now turn OFF
	bcf	ct_states, ON_A

	; control output was ON with a delay
	; now turn ON forever
	bcf	ct_states, DE_A
	return

bt_a_short
	; the button hold time was too short, ignore
	return

de_a_sub
	btfsc	ct_states, ON_A
	btfss	ct_states, DE_A
	return
	decfsz	ct_a_cnt, F
	return
	movf	ct_a_cnt+1, W
	btfsc	STATUS, Z
de_a_done
	bcf	ct_states, ON_A ; delay time elapsed

	decf	ct_a_cnt+1, F
	return

ct_a_sub
	btfss	ct_states, ON_A
	return
	bsf	port_state, CT_A
	btfsc	ct_states, DE_A
	bsf	port_state, LD_A
	return

bt_b_sub
	movf	bt_b, W
	movwf	prev_bt_b

	movlw	(1<<BT_B)
	andwf	GPIO, W
	movwf	bt_b

	xorwf	prev_bt_b, W
	bz	bt_b_unchanged

bt_b_changed
	; button status changed
	btfss	bt_b, BT_B
	goto	bt_b_released

bt_b_pressed
	; button pressed
	clrf	bt_b_cnt

bt_b_unchanged
	btfsc	bt_b, BT_B
	incf	bt_b_cnt, F ; measure pressing time
	return

bt_b_released
	; the button is just released
	movf	bt_b_holdtime, W
	subwf	bt_b_cnt, W
	bnc	bt_b_short

	; the button hold time was long enough
	btfsc	ct_states, ON_B
	goto	bt_b_tst1

	; control output was OFF
	; now turn ON and setup delay
	bsf	ct_states, ON_B
	bsf	ct_states, DE_B

	; setup delay
	movf	ct_b_time, W
	movwf	ct_b_cnt
	movf	ct_b_time+1, W
	movwf	ct_b_cnt+1
	return

bt_b_tst1
	btfss	ct_states, DE_B ; comment this line out to not turn ON forever

	; control output was ON forever
	; now turn OFF
	bcf	ct_states, ON_B

	; control output was ON with a delay
	; now turn ON forever
	bcf	ct_states, DE_B
	return

bt_b_short
	; the button hold time was too short, ignore
	return

de_b_sub
	btfsc	ct_states, ON_B
	btfss	ct_states, DE_B
	return
	decfsz	ct_b_cnt, F
	return
	movf	ct_b_cnt+1, W
	btfsc	STATUS, Z
de_b_done
	bcf	ct_states, ON_B ; delay time elapsed

	decf	ct_b_cnt+1, F
	return

ct_b_sub
	btfss	ct_states, ON_B
	return
	bsf	port_state, CT_B
	btfsc	ct_states, DE_B
	bsf	port_state, LD_B
	return

	end                       ; directive 'end of program'